IEC 61131-3 ⇄ 10変換器 Jiecc

Jiecc とは

Jieccは、IEC 61131-3のテキストをIEC 61131-10 XMLに変換、又は逆変換するツールです。

Windows 7以降の64bit OSにて動作するコマンドライン版と、ブラウザ上で実行できるWeb版があります。

例えば、以下のIEC 61131-3テキストをIEC 61131-10 XMLに変換します。

// User defined types
type
	// Enum type
	e_t: (e0, e1);
	// Struct type
	t_t: struct
		m0: int;
		// Array member
		m1: array[0..7] of bool;
	end_struct;
end_type

// Program POU
program Main
	// Static variables
	var
		i: int;
		vs: array[0..2] of int := [2, 3, 5];
		ev: e_t := e0;
		tv: t_t := (m0 := 7, m1 := [8(true)]);
	end_var
// Body program section requires `{st}` and `{end}` pragmas.
// {st}
for i := 0 to 2 by 1 do
	vs[i] := vs[i] + i;
end_for;
// {end}
end_program

<?xml version="1.0" encoding="utf-8"?>
<Project xmlns="www.iec.ch/public/TC65SC65BWG7TF10" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="www.iec.ch/public/TC65SC65BWG7TF10 IEC61131_10_Ed1_0.xsd" schemaVersion="1.0">
<FileHeader companyName="" productName="" productVersion="" />
<ContentHeader name="" creationDateTime="2024-06-29T00:00:00+09:00" />
<Types><GlobalNamespace>
<DataTypeDecl name="e_t">
<UserDefinedTypeSpec xsi:type="EnumTypeSpec">
	<Enumerator name="e0" />
	<Enumerator name="e1" />
</UserDefinedTypeSpec>
</DataTypeDecl>
<DataTypeDecl name="t_t">
<UserDefinedTypeSpec xsi:type="StructTypeSpec">
	<Member name="m0">
		<Type><TypeName>int</TypeName></Type>
	</Member>
	<Member name="m1">
		<Type><InstantlyDefinedType xsi:type="ArrayTypeSpec"><BaseType><TypeName>bool</TypeName></BaseType><DimensionSpec dimensionNumber="1"><IndexRange lower="0" upper="7" /></DimensionSpec></InstantlyDefinedType></Type>
	</Member>
</UserDefinedTypeSpec>
</DataTypeDecl>
<Program name="Main">
	<Vars accessSpecifier="private">
		<Variable name="i">
			<Type><TypeName>int</TypeName></Type>
		</Variable>
	</Vars>
	<Vars accessSpecifier="private">
		<Variable name="vs">
			<Type><InstantlyDefinedType xsi:type="ArrayTypeSpec"><BaseType><TypeName>int</TypeName></BaseType><DimensionSpec dimensionNumber="1"><IndexRange lower="0" upper="2" /></DimensionSpec></InstantlyDefinedType></Type>
			<InitialValue>
				<ArrayValue>
					<Value>
						<SimpleValue value="2" />
					</Value>
					<Value>
						<SimpleValue value="3" />
					</Value>
					<Value>
						<SimpleValue value="5" />
					</Value>
				</ArrayValue>
			</InitialValue>
		</Variable>
	</Vars>
	<Vars accessSpecifier="private">
		<Variable name="ev">
			<Type><TypeName>e_t</TypeName></Type>
			<InitialValue>
				<SimpleValue value="e0" />
			</InitialValue>
		</Variable>
	</Vars>
	<Vars accessSpecifier="private">
		<Variable name="tv">
			<Type><TypeName>t_t</TypeName></Type>
			<InitialValue>
				<StructValue>
					<Value member="m0">
						<SimpleValue value="7" />
					</Value>
					<Value member="m1">
						<ArrayValue>
							<Value repetitionValue="8">
								<SimpleValue value="true" />
							</Value>
						</ArrayValue>
					</Value>
				</StructValue>
			</InitialValue>
		</Variable>
	</Vars>
	<MainBody>
		<BodyContent xsi:type="ST"><ST>for i := 0 to 2 by 1 do
	vs[i] := vs[i] + i;
end_for;
</ST></BodyContent>
	</MainBody>
</Program>
</GlobalNamespace></Types>
<Instances>
</Instances>
</Project>

IEC 61131-10 XML規格の目的の一つは、PLCメーカー間等の相互データ交換を容易にすることですが、ヒトがIEC 61131-10 XMLを直接書くのは非効率です。Jieccは、可読性もありヒトでも書けるIEC 61131-3テキストをIEC 61131-10 XMLに自動変換することにより、メーカー間等の相互データ交換を維持しつつ、可読性のあるIEC 61131-3テキストで制御プログラムやライブラリを管理することを可能にします。

Jieccはプリプロセス機能をもちます。

{#define DECL_ADD_FUNCTION(T)
	function add_@@T: T
	var_input
		in1, in2: T;
	end_var
	${st$}
	add_@@T := in1 + in2;
	${end$}
	end_function
}

DECL_ADD_FUNCTION(int)
DECL_ADD_FUNCTION(lreal)

function add_int: int
	var_input
		in1, in2: int;
	end_var
	{st}
	add_int := in1 + in2;
	{end}
end_function

function add_lreal: lreal
	var_input
		in1, in2: lreal;
	end_var
	{st}
	add_lreal := in1 + in2;
	{end}
end_function

Jieccのもう一つの機能であるIEC 61131-10 XMLからIEC 61131-3テキストへの逆変換は、あるIEC 61131-10 XMLを生成するソフトウェア（e.g. Mathworks^® PLC Coder R2023b以降, PLCnext Engineer 2024.0 LTS以降, CODESYS V3.5.21.0, March 2025以降）が生成したXMLをIEC 61131-3テキストに変換して管理するときなどに有用です。

Jieccのダウンロードと実行方法

Download Jiecc!からzipファイルをダウンロードし解凍すると、次のファイルが展開されます。

jiecc.exe           ; Jiecc実行ファイル本体です。
LICENSE.txt         ; Jieccのライセンス情報です。
jiecc_homepage.url  ; 本サイトへのショートカット
iec_61131_sample/   ; IEC 61131-3テキストと、対応するIEC 61131-10 XMLのサンプルです。
    standard/       ; IEC 61131-10規格準拠のXMLとIEC 61131-3テキストです。
    omron/          ; オムロン社製Sysmac Studio準拠のXMLとIEC 61131-3テキストです。
    keyence/        ; キーエンス社製KV STUDIO準拠のXMLとIEC 61131-3テキストです。5.2~
    mitsubishi/     ; 三菱電機社製GX Works 3準拠のXMLとIEC 61131-3テキストです。5.4~
    codesys/        ; CODESYS社製CODESYS準拠のXMLとIEC 61131-3テキストです。5.8~

変換を実行するには、Windowsのコマンドプロンプト等を起動後、jiecc.exeのあるフォルダに移動し、次の形式でコマンドを入力します。

$ jiecc.exe <入力IEC 61131-3テキストファイルパス> -o <出力IEC 61131-10 XMLファイルパス>

例えば、次のコマンドを入力すると、実行フォルダにenum.xmlが出力されます。

$ jiecc.exe .\iec_61131_sample\standard\enum.txt -o enum.xml

上記コマンドでは、IEC 61131-10規格準拠のXMLを出力します。オムロン社製Sysmac Studio準拠のXMLを出力する場合、コマンドラインオプションに `-t omron` を付加します。 see ターゲット一覧

$ jiecc.exe .\iec_61131_sample\omron\enum.txt -t omron -o enum.xml

IEC 61131-10 XMLをIEC 61131-3テキストに逆変換するには、-dオプションをつけます。

$ jiecc.exe -d <入力IEC 61131-10 XMLファイルパス> -o <出力IEC 61131-3テキストファイルパス>

IEC 61131-3テキストにプリプロセスのみを適用した結果を得るには、-Eオプションをつけます。標準出力にプリプロセス後のIEC 61131-3テキストが出力されます。

$ jiecc.exe -E <入力IEC 61131-3テキストファイルパス>

`jiecc.exe --version`で、jieccのバージョンを確認できます。

その他のjieccコマンドのオプションについては、`jiecc.exe --help`にて確認できます。Jiecc 4.16.14のコマンド実行結果は以下の通りです。

usage: jiecc.exe [-h] [--version] [--output OUTPUT] [--output_iec_61131_10 | --output_iec_61131_3] [--define-macro DEFINE_MACRO] [--syspath SYSPATH] [--target TARGET] [--line-separator LINE_SEPARATOR] [--retro_caps]
	[--max-include-depth MAX_INCLUDE_DEPTH] [--recursion-limit RECURSION_LIMIT] [--preprocess-only] [--pp-output-pragma-style PP_OUTPUT_PRAGMA_STYLE] [--remove-comments] [-dM] [--silent] [--set SET]
	[filepath ...]

Jiecc is an IEC 61131-3 <-> IEC 61131-10 converter/deconverter.

It converts IEC 61131-3 text to IEC 61131-10 XML and vice versa.

Typical usage:
jiecc <IEC 61131-3 text filepath> -o <IEC 61131-10 XML filepath>
or
jiecc -d <IEC 61131-10 XML filepath> -o <IEC 61131-3 text filepath>

For additional details, visit:
https://www.graviness.com/iec_61131_3/jiecc.html

positional arguments:
filepath              the IEC 61131-3 text file path in -c mode, or the IEC 61131-10 xml file path in -d mode.

options:
-h, --help            show this help message and exit
--version             show program's version number and exit
--output OUTPUT, -o OUTPUT
		   the output XML file path in -c mode, or the output text file path in -d mode. Default: STDOUT (outputs to standard output.)
--output_iec_61131_10, -c
		   the mode output in IEC 61131-10 XML.
--output_iec_61131_3, -d
		   the mode output in IEC 61131-3 text.
--define-macro DEFINE_MACRO, -D DEFINE_MACRO
		   define a macro. -D <macro> to set <macro> to 1 or -D<macro>=<value> to assign a specific value. e.g. -D DEBUG, -D V=10.
--syspath SYSPATH, -I SYSPATH
		   add the directory SYSPATH to the list of directories to be searched for (s)include/(s)import files.
--target TARGET, -t TARGET
		   conversion target. e.g. OMRON, KEYENCE. Default: STD.
--line-separator LINE_SEPARATOR, -N LINE_SEPARATOR
		   newline code for the output. e.g. LF, CRLF, CR. Default: LF.
--retro_caps          output IEC 61131-3 keywords in uppercase.
--max-include-depth MAX_INCLUDE_DEPTH
		   the maximum depth of the nested #include. The default is 200.
--recursion-limit RECURSION_LIMIT
		   the maximum recursion depth allowed by the program. The default is the system default value.
--preprocess-only, -E
		   preprocessed only.; do not convert.
--pp-output-pragma-style PP_OUTPUT_PRAGMA_STYLE
		   The format of preprocessor output pragmas. Possible values: annotated (*{~}*) or standard {~}. Default: annotated.
--remove-comments, -nC
		   remove comments in preprocessed output. The default is False.
-dM                   generate a list of #define directives for all the macros defined during the execution of the preprocessor, including predefined macros. must be invoked with -E.
--silent              activate silent mode to suppress error messages.
--set SET             set and lock options. e.g. creation-datetime=1999-12-31T23:59:59.999+11:59.

Jiecc Web版

以下のフォームを使用して、ブラウザ上でIEC 61131-3テキストをIEC 61131-10 XMLへ変換できます。

Jieccの仕様

Jieccの入力仕様や特性について記載します。

エンコーディング方式

JieccがサポートするIEC 61131-3テキストのエンコーディング方式は、UTF-8です。改行コードは、LF、CRLF、CRをサポートします。

validation機能

Jieccは、構文検査機能を持ちますが、意味解析レベルのvalidation機能を持ちません。入力のIEC 61131-3テキストを可能な限り、IEC 61131-10 XMLに変換しようとします。

例えば、次のIEC 61131-3テキストは、同じ名前の変数aがプログラムPOUに定義されているため、IEC 61131-3の仕様的には不正なプログラムです。しかし、Jieccはこれを異常とせず、var_tempのaとvarのaを含むIEC 61131-10 XMLを生成します。

program Main
	var_temp a: bool; end_var
	var a: int; end_var
end_program

また、ファンクション内でvar変数（静的変数）を定義している次のプログラムは、IEC 61131-3の仕様的には正しいですが、IEC 61131-10 XMLの仕様では不正となります。このようなプログラムについても、Jieccは可能な限り、XMLを生成しようとします。

function f: bool
	var v: int; end_var // IEC 61131-10的には不正
end_function

最終的な確認は、IEC 61131-10をサポートする以下の環境にて行ってください。

• オムロン社製Sysmac Studio Ver.1.30以降
• キーエンス社製KV STUDIO Version 12以降
• 三菱電機社製MELSOFT GX Works3 Ver.1.110Q以降
• CODESYS社製CODESYS V3.5.21.0, March 2025以降
• Phoenix Contact社製PLCnext Engineer 2024.0 LTS以降

ST言語などのプログラムコード部の記述方法

ST言語のプログラムコードをPOU内に記述するには、プラグマ{st}~{end}を使用して次のように記述します。

program Main
	var intv: int; end_var
//{st}
intv := 3;
intv := intv + 1;
//{end}
end_program

上記は次のように出力されます。{st}~{end}内の文字列がそのまま出力されます。get-line, __line__プラグマ等も置換されずそのまま出力されることに注意ください。プリプロセス機能の__LINE__マクロであれば置換されます。

:
<Program name="Main">
	:
	<MainBody>
		<BodyContent xsi:type="ST"><ST>intv := 3;
intv := intv + 1;
</ST></BodyContent>
	</MainBody>
</Program>
:

LD言語のプログラムコードをPOU内に記述するには、同様に{ld}~{end}を使用して次のように記述します。IEC 61131-10 XMLのラダープログラム部分をそのまま記述します。

program Main
	var o: bool; end_var
//{ld}
<Rung evaluationOrder="1">
:
</Rung>
//{end}
end_program

上記は次のように出力されます。同様に{ld}~{end}内の文字列がそのまま出力されます。

:
<Program name="Main">
	<Vars accessSpecifier="private">
		<Variable name="o">
			<Type><TypeName>BOOL</TypeName></Type>
		</Variable>
	</Vars>
	<MainBody>
		<BodyContent xsi:type="LD">
<Rung evaluationOrder="1">
:
</Rung>
		</BodyContent>
	</MainBody>
</Program>
:

FBD言語、SFC言語、IL言語も同様に{fbd}~{end}、{sfc}~{end}、{il}~{end}を使用します。具体的な記述例は、jiecc.zipに同梱されているサンプルを参照してください。

サポート要素

JieccのIEC 61131-3言語要素のサポート状況は下表の通りです。Yesのない要素は、未サポートか又はテストされていません。"サポート -c"は、IEC 61131-3→IEC 61131-10変換のサポート状況、"サポート -d"は、IEC 61131-10→IEC 61131-3変換のサポート状況です。Jiecc 4.x以降において、IEC 61131-3およびIEC 61131-10のすべての機能をサポートしています。ただし、変換できたとしても各メーカーが読み込み、さらに動作するかどうかは、各メーカーのIEC 61131-3対応状況に依存します。

プラグマ

IEC 61131-10にはいくつかの必須属性があり、FileHeaderタグのcompanyName（会社名）属性はその一つです。もちろん、IEC 61131-3にはこの属性を指定する正式な方法は存在しませんが、IEC 61131-10の必須属性ですので、設定できなければ困ります。

この問題の解決に、IEC 61131-3のプラグマを使用します。プラグマは、IEC 61131-3をサポートするメーカーの独自拡張のためにも使用できます。{pragma_key pragma_value}のように記述しますが、{~}の内容にIEC 61131-3の特別な規定はありません。メーカーが独自に規定します。Jieccでは、IEC 61131-10の必須属性の設定のためだけでなく、C言語のプリプロセッサのlineディレクティブ相当や、IEC 61131-10に埋め込む要素のコメントなど、IEC 61131-3でサポートされない様々なことを実現するために活用します。Jieccがサポートするプラグマについては、本節で説明しています。

一方、プラグマの構文{~}をサポートしているメーカーは少なく、メーカーのエディタ上に書くと構文エラーを発生させます。Jieccでは、構文エラーを発生させないために、{~}の記法に加え、次の3つの記法をサポートしています。これらは全てJiecc固有のプラグマの別記法です。この記法はIEC 61131-3規定のコメントの中に記述されていますので、どのメーカーにとっても無害とできます。

//{~}
(*{~}*)
/*{~}*/

Jiecc固有の仕様として、プラグマの構文は、{key value}4.2.0~、又はコロンで区切る{key:value}です。valueの指定を必要としないプラグマについては、{key}4.2.0~、又は{key:}のように記述します。

プラグマ内で自由に改行できます。5.10~プラグマ内で改行するには、$に続いて改行します。

{doc: メインプログラム
---
メインプログラムの説明を記述します。}
program Main end_program

ただし、プラグマ内の改行は、プリプロセス機能により早い段階で改行そのものが削除されコンバート処理が実行されます。上記の例は文法的に間違ってはいませんが、プラグマ内で改行に意味がある場合、次のように$nを記述します。

{doc: メインプログラム$n
---$n
メインプログラムの説明を記述します。}
program Main end_program

Jieccのコマンドラインから指定できるオプションの多くは本章で示すプラグマでも指定できます。両方指定している場合、コマンドラインオプションが優先されます。

IEC 61131-10 Headerタグの属性に関するプラグマ

下表のプラグマは、出力するIEC 61131-10 XMLのFileHeaderタグの属性値、又はContentHeaderタグの属性値を指定します。

IEC 61131-10 XML必須の属性については、下表に示すデフォルト値が設定されています。

creation-datetime、およびmodification-datetimeの値には、2023-09-01T00:00:00+09:00のような日付時刻を直接指定する他にTODAY、およびNOWを指定できます。それぞれ、本日の日付（時刻を00:00:00固定）、今の時間（秒含めて正確）に置き換えられます。

// {company-name: Jiecc Corp.}
// {company-url: https://www.graviness.com/iec_61131-3/jiecc.html}
// {content-name: Xxx装置}

docプラグマ

docプラグマは、IEC 61131-10 XMLのDocumentationタグに相当し、変数などの要素のコメントを付加するために使用します。コメントを付加する要素の宣言の前に記述します。

type
	// {doc: RGBカラーです。}
	color_t: ((*{doc: 赤}*) red, (*{doc: 緑}*) green, (*{doc: 青}*) blue);
end_type

// {doc: ファンクションfのコメントです。}
function f: dint
	var_input
		// {doc: 入力変数inのコメントです。}
		in: dint;
	end_var
end_function

orderプラグマ

orderプラグマは、IEC 61131-10 XMLの引数変数宣言に対するorderWithinParamSet属性を設定します。

function f: bool
	var_input
		i_third: int (*{order: 3}*);
		i_first: int (*{order: 1}*);
		i_second: int (*{order: 2}*);
	end_var
end_function

evaluation-orderプラグマ

evaluation-orderプラグマは、IEC 61131-10 XMLのプログラムインスタンス宣言に対するevaluationOrder属性を設定します。

configuration cfg
	resource rsc on plc
		task tsk_fast(INTERVAL := t#500us, PRIORITY := 1);

		program task1 with tsk_fast: p1() (*{evaluation-order: 1}*);
		program task2 with tsk_fast: p2() (*{evaluation-order: 2}*);
	end_resource
end_configuration

include, sincludeプラグマ

includeプラグマ、およびsincludeプラグマは、C言語プリプロセッサのincludeディレクティブに相当し、指定のパスにあるファイルを読み込みます。

{include: lib/x.txt}

program Main end_program

lib/x.txtの内容が、program Sub end_programであれば、以下のソースコードを入力したことと等価になります。

program Sub end_program

program Main end_program

4.12~IEC 61131-10 XMLを直接読み込むことができます。{include: x.xml}のように拡張子をxmlにします。

includeプラグマとsincludeプラグマの違いは、ファイルの探し方（下表参照）です。考え方は、C言語プリプロセッサの#include "~"と#include <~>と同じです。

例えば、{include: lib/x.txt}と記述したファイルがsrcディレクトリにある場合、src/lib/x.txtを探して読み込みます。

4.8.10~パス部分を{include <~>}のように<~>で囲うと、{sinclude ~}と同等の動作になります。

syspathプラグマ

syspathプラグマは、sincludeプラグマが探索するディレクトリを追加します。

指定するパスが相対パスのとき、Jieccの実行ディレクトリを基準にします。Jieccの実行ディレクトリが変わる場合は、注意してください。sincludeプラグマが探索するディレクトリは、Jieccのコマンドラインオプション --syspath (-I) によっても指定できます。

{syspath: common/lib/random}
{syspath: ./../submoodule}

// ./common/lib/random/mt.txt, または ./../submodule/mt.txt を探します。
{sinclude: mt.txt}

line-separatorプラグマ

line-separatorプラグマは、IEC 61131-10 XML出力時、またはIEC 61131-3テキスト出力時の改行文字を指定します。

// XMLの改行をCR-LFで出力します。
// {line-separator: $r$n}

targetプラグマ

targetプラグマは、変換先のターゲットを指定します。デフォルト値は、STD（IEC 61131-10規格準拠）です。

本プラグマは、主に、当該ターゲットによるIEC 61131-3やIEC 61131-10規格の独自解釈部分や独自拡張をサポートするためにあります。

// {target: OMRON}

program Main
	var
		a: array[0..2] of int := [1, 2, 3];
	end_var
end_program

現在サポートしているターゲット一覧を下表に示します。

IEC 61131-10のインポート動作未確認ですが、値 PHOENIXCONTACT も有効に機能します。5.4~

idプラグマ

idプラグマは、IEC 61131-3では記述することが難しいパス文字列や識別子を記述します。

var
	// vのat属性値は半角空白を含む'%xxx://x y 3'になります。
	v at {id: %xxx://x y 3} : bool;
end_var

set-line, lineプラグマ

set-line, lineプラグマは、C言語プリプロセッサのlineディレクティブに相当し、プラグマを記述した行の番号がプラグマで指定した番号になります。

{set-line: 4}

program Main // mainは6行目で定義された要素と解釈されます。
end_program

get-line, __line__プラグマ

get-line, __line__プラグマは、C言語プリプロセッサの__LINE__マクロに相当し、プラグマが行番号に置換されます。

get-line, __line__プラグマは、ST, LD, FBD, SFC, ILプラグマ内では、置換されないことに注意してください。プリプロセス機能の__LINE__マクロを使用すれば置換されます。

retro_capsプラグマ

retro_capsプラグマは、IEC 61131-3キーワードを小文字で出力するか、大文字で出力するかを制御します。

デフォルトは、小文字で出力します。{retro_caps: true}とすると大文字で出力します。

__func__プラグマ

4.18~__func__プラグマは、C言語の__func__変数に相当する機能を提供します。POUの属性として記述するとき、__func__プラグマの値で指定する変数名の当該POU単純名を初期値にもつ文字列型変数を自動生成します。

program {__func__:this_pouname} Main
var s: string[32]; end
{st}
s := this_pouname; // s = 'Main' となります。
{end}
end_program

上記プログラムは以下のプログラムと等価です。

program Main
var s: string[32]; end
var constant this_pouname: string[5] := 'Main'; end
{st}
s := this_pouname; // s = 'Main' となります。
{end}
end_program

single-bodyプラグマ

4.18~一つのPOUが複数のコードブロックで記述されるとき、対応するXMLにおいてもそのまま複数のコードブロックでXMLを出力します。single-bodyプラグマを使用すると、複数のコードブロックを一つのコードブロックにまとめたXMLを出力します。

program {single-body: true} Main
var v: int; end_var
{st}
v := 2;
{end}
var t: dint; end_var
{st}
t := 3;
{end}
end_program

上記プログラムは以下のプログラムと等価です。

program Main
var v: int; end_var
var t: dint; end_var
{st}
v := 2;
t := 3;
{end}
end_program

append-eilogue-pou-bodyプラグマ

5.4~いくつかのターゲットにおいては、そのターゲット環境の特性が理由で、XML生成時に自動でプログラムを挿入することがあります。例えば、キーエンス社製KV STUDIOがターゲットの場合、POUのXML生成時に、END・ENDH命令を含むラダープログラムを自動挿入します。append-eilogue-pou-bodyプラグマを使用すると、この自動挿入を抑制することができます。自動挿入を抑制したい場合、{append-eilogue-pou-body: false}のように記述します。append-eilogue-pou-bodyプラグマは、個々のPOUに対してではなく、コンバート単位全体に対して適用されます。

// {append-eilogue-pou-body: false}

function func_1: bool end_function
function func_2: bool end_function

return-docプラグマ

return-docプラグマは、戻り値変数のコメントを指定するために使用します。

IEC 61131-10に対応する要素はなく、ターゲットがOMRONのときのみ機能します。

// {doc: ファンクションfのコメントです。}
// {return-doc: 戻り値変数のコメントです。}
function f: bool end_function

FunPouProperties.isEnEno, FbPouProperties.isEnEnoプラグマ

5.4~FunPouProperties.isEnEno, FbPouProperties.isEnEnoプラグマは、それぞれファンクションとファンクションブロックの属性であり、三菱電機社製MELSOFT GX Works3 Ver.1におけるPOUのプロパティ「EN/ENOを使用する」を指定するために使用します。

function {FunPouProperties.isEnEno: true} func: bool end_function

ST, LD, FBD, SFC, IL, ENDプラグマ

ST, LD, FBD, SFC, ILプラグマは、ENDプラグマと併用して使用し、ST/LD/FBD/SFC/IL言語のプログラムコードを記述するために使用します。詳しくは、ST言語などのプログラムコード部の記述方法を参照ください。

プリプロセス機能

Jieccはプリプロセス機能を持ちます。IEC 61131-3テキストをIEC 61131-10 XMLに変換する過程において、最初にプリプロセスを実行します。プリプロセスでは、主に以下の処理を行います。

• プラグマ構文{~}内の$に続く改行文字を検出すると、その2文字を削除します。5.10~同様に、改行文字を検出した場合も、その改行文字を削除します。本処理は、プリプロセス処理の中でも最初に行われます。
• プログラマが#defineディレクティブで定義したマクロの置換や事前定義されているマクロの置換を行います。
• 4.4.0~プログラマが記述した#if, #elif, #else, #endifディレクティブを評価し、ソースコードの有効部分と無効部分を切り分けます。この処理は、マクロの置換と並行して行います。

その後、IEC 61131-3テキストの構文解析が続きます。プリプロセスのみを適用するには、Jieccのコマンドラインオプションに-Eをつけます。

プリプロセスでは、本節で示すシステム定義のマクロとプリプロセッサディレクティブがあります。

事前定義マクロ

4.4.0~Jieccは、ターゲットやコマンドラインオプションに応じて、特定のプリプロセッサマクロを事前に定義します。Jiecc 5.8.4にて、`jiecc -dM - < /dev/null`した結果は次の通りです。

{#define __SINT_MIN__ -128}
{#define __SINT_MAX__ 127}
{#define __INT_MIN__ -32768}
{#define __INT_MAX__ 32767}
{#define __DINT_MIN__ -2147483648}
{#define __DINT_MAX__ 2147483647}
{#define __LINT_MIN__ -9223372036854775808}
{#define __LINT_MAX__ 9223372036854775807}
{#define __USINT_MIN__ 0}
{#define __USINT_MAX__ 255}
{#define __UINT_MIN__ 0}
{#define __UINT_MAX__ 65535}
{#define __UDINT_MIN__ 0}
{#define __UDINT_MAX__ 4294967295}
{#define __ULINT_MIN__ 0}
{#define __ULINT_MAX__ 18446744073709551615}
{#define __BYTE_MASK__ byte#16#ff}
{#define __WORD_MASK__ word#16#ffff}
{#define __DWORD_MASK__ dword#16#ffffffff}
{#define __LWORD_MASK__ lword#16#ffffffffffffffff}
{#define __LTIME_MIN__ time#-9223372036854775808ns}
{#define __LTIME_MAX__ time#9223372036854775807ns}
{#define __LTIME_MIN_IN_NS__ -9223372036854775808}
{#define __LTIME_MAX_IN_NS__ 9223372036854775807}
{#define __LDATE_MIN__ ldate#1970-01-01}
{#define __LDATE_MAX__ ldate#2554-07-21}
{#define __LTOD_MIN__ ldate#1970-01-01}
{#define __LTOD_MAX__ ldate#2554-07-21}
{#define __LDT_MIN__ ldate#1970-01-01-00$:00$:00}
{#define __LDT_MAX__ ldate#2554-07-21-23$:34$:33.709551615}
{#define __INT8_TYPE sint}
{#define __INT16_TYPE int}
{#define __INT32_TYPE dint}
{#define __INT64_TYPE lint}
{#define __UINT8_TYPE usint}
{#define __UINT16_TYPE uint}
{#define __UINT32_TYPE udint}
{#define __UINT64_TYPE ulint}
{#define __BITS8_TYPE byte}
{#define __BITS16_TYPE word}
{#define __BITS32_TYPE dword}
{#define __BITS64_TYPE lword}
{#define _JIECC true}
{#define _JIECC_FULL_VER 50804}
{#define _JIECC_VER 508}
{#define _JIECC_VERSION '5.8.4'}
{#define _STD true}
{#define _STANDARD true}
{#define _OMRON false}
{#define _OM false}
{#define _OMRON_SYSMAC false}
{#define _PHOENIXCONTACT false}
{#define _PH false}
{#define _PHOENIXCONTACT_PLCNEXT false}
{#define _KEYENCE false}
{#define _KE false}
{#define _KEYENCE_KVST false}
{#define _MITSUBISHI false}
{#define _MI false}
{#define _MITSUBISHI_GXWORKS3 false}
{#define _CODESYS false}
{#define _CO false}
{#define _CODESYS_CODESYS false}

__LINE__マクロ

__LINE__マクロは、ソースコードの行番号に置換されます。

program Main
var v: int; end_var
{st}
v := __LINE__; // v := 4;
{end}
end_program

__FILE__マクロ

__FILE__マクロは、ソースコードのファイルパスの文字列リテラルに置換されます。

program Main
var
	v: string := __FILE__; // 本ファイルのファイルパスが"a.txt"であれば、v: string := 'a.txt'; です。
end_var
end_program

__COUNTER__マクロ

__COUNTER__マクロは、整数リテラルに置換されます。0から始まり、置換が発生するたびにインクリメントされます。#includeした場合もリセットされることはありません。

program Main
var v: int; end_var
//{st}
v := __COUNTER__; // v := 0;
v := __COUNTER__; // v := 1;
v := __COUNTER__; // v := 2;
//{end}
end_program

__DATE__, __TIME__マクロ

4.4.0~__DATE__, __TIME__マクロは、それぞれソースコードのコンパイル日付とコンパイル時刻の文字列リテラルに置換されます。

program Main
	var
		compile_datev: string := __DATE__; // 'Dec 02 2024' などを得ます。
		compile_todv: string := __TIME__; // '01:02:03' などを得ます。
	end_var
end_program

__TIMESTAMP__マクロ

4.4.0~__TIMESTAMP__マクロは、現在のソースファイルが最後に変更された日付日時の文字列リテラルに置換されます。

program Main
	var
		lastmodified_datev: string := __TIMESTAMP__; // 'Mon Dec 09 01:02:03 2024' などを得ます。
	end_var
end_program

#defineディレクティブ

#defineディレクティブは、識別子に対して文字列を関連付けを定義し、以降のソースコード内で当該識別子が現れると関連付けている文字列で置換します。

既に同じ識別子に関連付けがある場合、警告を出力します。ただし、内容が同じであれば警告を出力しません4.4.0~。#defineディレクティブは、オブジェクトマクロと、引数をもつ関数マクロがあります。

{#define identifier tokensopt}

上記形式で記述するオブジェクトマクロは、identifierにtokensを関連付けます。tokensを省略する場合、空文字列を関連付けます。

{#define KEY_TYPE uint}
{#define VALUE_TYPE lreal}

type
	Pair_t: struct
		key: KEY_TYPE; // key: uint;
		value: VALUE_TYPE; // value: lreal;
	end_struct;
end_type

function Pair_init
var_in_out self: Pair_t; end_var
var_input
	key: KEY_TYPE; // key: uint;
	value: VALUE_TYPE; // value: lreal;
end_var
//{st}
self.key := key;
self.value := value;
//{end}
end_function

関数マクロ4.2.0~

{#define identifier(identifier,opt ...opt) tokensopt}

上記形式で記述する関数マクロは、括弧内のパラメータをtokens内で使用できます。

{#define SWAP(x, y, t) t := y; y := x; x := t}

program Main
var
	i: int := 2;
	j: int := 3;
	t: int;

	r: lreal := 5.0;
	s: lreal := 7.0;
	tmp: lreal;
end_var
//{st}
SWAP(i, j, t); // t := j; j := i; i := t;
SWAP(r, s, tmp); // tmp := s; s := r; r := tmp;
//{end}
end_program

次に示す例のように、単純に置換すれば無限再帰する関数マクロも無限再帰せずに可能な限り置換を行います。このような例でもgccのプリプロセッサと同じ結果を得ます。^※1

{#define F(x) H(x),G(x),F(x),x}
{#define G(x) H(x),G(x),F(x),x}
{#define H(x) H(x),G(x),F(x),x}

F(A); // H(A),H(A),G(A),F(A),A,F(A),A,H(A),G(A),F(A),A,G(A),F(A),A,F(A),A;
G(B); // H(B),G(B),H(B),G(B),F(B),B,B,G(B),H(B),G(B),F(B),B,G(B),F(B),B,B;
H(C); // H(C),H(C),G(C),H(C),G(C),F(C),C,C,H(C),H(C),G(C),F(C),C,F(C),C,C;

5.10~#defineディレクティブ内で自由に改行できます。

{#define SWAP(x, y, t)
	t := y;
	y := x;
	x := t;
}

なお、#defineディレクティブ内でプラグマを記述する場合、${st$}~${end$}などと$でエスケープする必要があることに注意してください。

※1 Dave Prosser's C Preprocessing Algorithm

文字列化演算子 @4.2.0~

@演算子に続くパラメータを文字列リテラル化します。

{#define VAR_MSG(var) CONCAT(@var, ':', var)}

program Main
var
	my_var: string[100];
	msg: string[100];
end_var
//{st}
msg := VAR_MSG(my_var); // msg := CONCAT('my_var', ':', my_var);
//{end}
end_program

トークン連結演算子 @@4.2.0~

@@演算子の前後のトークンを連結します。

{#define DECL_VAR(name, type) name@@_@@type: type}

program Main
var
	DECL_VAR(my, int); // my_int: int;
	DECL_VAR(my, lreal); // my_lreal: lreal;
end_var
end_program

可変個引数マクロ4.2.0~

可変個引数マクロは、関数マクロの引数に可変個数のパラメータを指定できるようにしたものです。

可変個引数部分を参照するには、__VA_ARGS__マクロを使用します。

{#define MSG(kind, ...) CONCAT(kind, __VA_ARGS__)}

program Main
	var
		msg: string[100];
	end_var
	//{st}
	msg := MSG('severe', '0'); // msg := CONCAT('severe', '0');
	msg := MSG('error',  '1', 'redefine'); // msg := CONCAT('error', '1', 'redefine');
	//{end}
end_program

4.18~可変個引数部分の引数個数を得るには、__VA_ARGC__マクロを使用します。

{#define INITIALIZED_ARRAY_TYPE(basetype, ...) array[__VA_ARGC__] of basetype := [__VA_ARGS__]}

program Main
	var
		a: INITIALIZED_ARRAY_TYPE(int, 10, 20, 30); // a: array[3] of int := [10,20,30];
	end
end_program

#undefディレクティブ

#undefディレクティブは、#defineディレクティブによる定義を削除します。関連付けがなければ、何も起きません。

{#define T int} // 識別子Tにintを関連付けします。
function_block fb1
	var
		v: T; // v: int;
	end_var
end_function_block

{#undef T} // 識別子Tへの関連付けを削除します。
{#define T real} // 識別子Tにrealを関連付けします。
function_block fb2
	var
		v: T; // v: real;
	end_var
end_function_block
{#undef T} // 識別子Tへの関連付けを削除します。

#if, #ifdef, #ifndef, #elif, #else, #endifディレクティブ

4.4.0~#if, #ifdef, #ifndef, #elif, #else, #endifディレクティブは、ソースコード内の各ブロックの有効・無効を制御します。#ifの引数が0以外の整数値、又は真偽値trueになる場合、その後の一連のブロックは有効で保持されます。#ifの引数が整数値0、又は真偽値falseになる場合、その後の一連のブロックは無効となり、ソースコードに存在しなかったものと同等に扱われます。

#ifdef, #ifndefディレクティブは、#ifディレクティブが登場可能な場所に登場可能であり、#ifディレクティブ同様、ソースコード内の各ブロックの有効・無効を制御します。#ifdefの引数で指定する識別子が、マクロで定義されている場合、その後の一連のブロックは有効で保持されます。反対に、#ifndefの引数で指定する識別子が、マクロで定義されていない場合、その後の一連のブロックは有効で保持されます。#ifdef NAMEは、後述するdefined演算子を使用し、#if defined(NAME)と等価です。同様に、#ifndef NAMEは、#if not defined(NAME)と等価です。

なお、無効になっても行番号は維持されます。

{#define _RELEASE}

{#ifdef _RELEASE}
// _RELEASEマクロが定義されているため、本ブロックは有効です。このようなマクロは、通常、コマンドラインや別ファイルで定義されます。
function f: int end_function
{#else}
// 本ブロックは無効です。
function g: int end_function
function f: int end_function
{#endif}

以下の例において、_STD, _OMRON, 5.2~_KEYENCE, 5.4~_MITSUBISHIなどは、事前定義されるマクロの一つであって、コマンドラインオプション --target (-t) により制御できます。

program Main
{st}
{#if _OMRON}
// コマンドラインで、-t OMRON を指定した場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for OMRON body. */
{#elif _KEYENCE}
// コマンドラインで、-t KEYENCE を指定した場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for KEYENCE body. */
{#elif _MITSUBISHI}
// コマンドラインで、-t MITSUBISHI を指定した場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for MITSUBISHI body. */
{#elif _CODESYS}
// コマンドラインで、-t CODESYS を指定した場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for CODESYS body. */
{#elif _PHOENIXCONTACT}
// コマンドラインで、-t PHOENIXCONTACT を指定した場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for PHOENIXCONTACT body. */
{#elif _STD}
// コマンドラインで、-t STD を指定した場合、又は-tを指定していない場合、本ブロックは有効です。指定していない場合、本ブロックは無効です。
/* for STD body. */
{#else}
// コマンドラインで、-t OMRON, -t KEYENCE, -t MITSUBISHI, -t CODESYS, -t PHOENIXCONTACT, -t STD以外を指定した場合、本ブロックは有効です。
/* for OTHER body. */
{#endif}
{end}
end_program

defined演算子

defined演算子のオペランドに指定される識別子に関連するマクロが存在する場合にtrueと評価されます。

{#define X}
{#define Z_VALUE 0}

program Main
var
{#if defined(X)}
	// マクロXが定義されているため、このブロックは有効です。
	x: int;
{#endif}
{#if defined(Y)}
	// マクロYが定義されていないため、このブロックは無効です。
	y: int;
{#endif}
{#if defined(Z_VALUE)}
	// マクロZ_VALUEが定義されているため、このブロックは有効です。
	z: int := Z_VALUE;
{#else}
	// このブロックは無効です。
	z: int := 1;
{#endif}
end_var
end_program

###ディレクティブ

###ディレクティブは、記述された位置に文字列を展開します。

{#define T int}

function add_{### T}: T // function add_int: int
var_input
	in1, in2: T; // in1, in2: int;
end_var
//{st}
add_{### T} := in1 + in2; // add_int := in1 + in2;
//{end}
end_function

##ディレクティブ

##ディレクティブは、記述された位置に文字列リテラルを展開します。

'や$などは、展開時にエスケープされます。

program Main
var
	s: string := {## __COUNTER__}; // s: string := '0';
	i: int := __COUNTER__; // i: int := 1;
end_var
//{st}
s := {## __COUNTER__}; // s := '2';
i := __COUNTER__; // i := 3;
//{end}
end_program

#lineディレクティブ

#lineディレクティブは、エラー発生における行番号やファイル名を制御します。

{#line 行番号<空白文字>ファイル名}で指定します。ファイル名については省略可能です。__LINE__マクロ、__FILE__マクロに影響します。

program Proc1
var
	filename: string := __FILE__; // filename: string := 'ファイル名';
	lineno: int := __LINE__; // lineno: int := 4;
end_var
end_program

{#line 108 ./dir/new.txt}
program Proc2
var
	filename: string := __FILE__; // filename: string := './dir/new.txt';
	lineno: int := __LINE__; // lineno: int := 112;
end_var
end_program

#include, #sincludeディレクティブ

#include, #sincludeディレクティブは、C言語プリプロセッサのincludeディレクティブに相当し、指定のパスにあるファイルを読み込みます。

{#include lib/x.txt}

program Main end_program

lib/x.txtの内容が、program Sub end_programであれば、以下のソースコードを入力したことと等価になります。

program Sub end_program

program Main end_program

#includeディレクティブと#sincludeディレクティブの違いは、ファイルの探し方（下表参照）です。考え方は、C言語プリプロセッサの#include "~"と#include <~>と同じです。

例えば、{#include lib/x.txt}と記述したファイルがsrcディレクトリにある場合、src/lib/x.txtを探して読み込みます。

4.8.10~パス部分を{#include <~>}のように<~>で囲うと、{#sinclude ~}と同等の動作になります。

include, sincludeプラグマの機能と違う点は、#include, #sincludeディレクティブは、IEC 61131-10 XMLを直接読み込むことができないこと、そして、プリプロセスフェーズで読み込むか否かです。4.8.10~また、include, sincludeプラグマでは、ファイルの再帰的な呼び出しが許可されていませんが、#include, #sincludeディレクティブでは、許可されます。一方で、無限再帰を防止するため、呼び出しの深さが200で制限されています。この制限は、Jieccの--max-include-depthにより変更できます。

#syspathディレクティブ

#syspathディレクティブは、#sincludeディレクティブ、およびsincludeプラグマが探索するディレクトリを追加します。

指定するパスが相対パスのとき、Jieccの実行ディレクトリを基準にします。Jieccの実行ディレクトリが変わる場合は、注意してください。#sincludeディレクティブ、およびsincludeプラグマが探索するディレクトリは、Jieccのコマンドラインオプション --syspath (-I) によっても指定できます。

{#syspath common/lib/random}
{#syspath ./../submoodule}

// ./common/lib/random/mt.txt, または ./../submodule/mt.txt を探します。
{#sinclude mt.txt}

syspathプラグマとの違いは、プリプロセスフェーズで読み込むか否かです。#syspathディレクティブで設定したパスは、sincludeプラグマにも影響します。

#max-include-depthディレクティブ

4.16~#max-include-depthディレクティブは、#includeのネストの上限を変更します。初期値は、200です。

コマンドラインオプション max-include-depth によっても変更できます。

#errorディレクティブ

4.4~#errorディレクティブは、プリプロセス時にユーザ指定のエラーメッセージを出力して、処理全体を停止します。

{#if _STD}
// _STDが真の場合の処理を記述します。
{#else}
// _STDが偽の場合、以下のエラーメッセージ'Standard mode required.'を出力して停止します。
{#error Standard mode is required.}
{#endif}

#warning, #infoディレクティブ

4.16~#warning, #infoディレクティブは、プリプロセス時にユーザ指定のメッセージを出力します。処理全体は継続します。

{#if _STD}
// _STDが真の場合の処理を記述します。
{#else}
// _STDが偽の場合、以下のメッセージ'Standard mode is strongly recommended.'を出力します。
{#warning Standard mode is strongly recommended.}
{#endif}

拡張構文

Jieccは、IEC 61131-3の構文仕様を拡張した独自構文をサポートしています。IEC 61131-3準拠の構文のみを使用する必要がある場合、本章の内容に注意ください。

endキーワード

endキーワードは、あらゆる"始まり"の構文に対応する"終わり"として使用できます。

type
	t: struct m: int; end;
end

program Main
	var v: int; end
{st}
if true then v := 1; else v := 0; end;
{end}
end

末尾部分での変数属性の指定

(*
var constant
	v1: int := 2;
end_var
var constant retain
	v2: int := 3;
end_var
*)
// 以下は、上記宣言と等価です。
var
	v1: int constant := 2;
	v2: int constant retain := 3;
end_var

サイズ指定の配列宣言

4.18~配列宣言時に、始点と終点ではなく、サイズを指定する構文をサポートします。

var
	a: array[10] of int; // a: array[0..9] of int と等価です。
end_var

基数10の数値リテラル

基数10を指定するリテラルをサポートします。IEC 61131-3では、基数2, 8, 16のみ規定されています。

10#12; // 基数10の12、即ち12です。

コードブロック外における文字列リテラルの連結

コードブロック外において、トークン的に連続する文字列リテラルがあるとき、一つの文字列リテラルに連結します。本機能は、プリプロセス時とコンバート時の両方で実行されます。

var
	// 'シンボル,値$nPI,3.14159$nE,2.71828$n'と等価です。
	stringv: string[100] := 'シンボル,値' '$n'
		'PI,3.14159' '$n'
		'E,2.71828' '$n'
		;
end_var

末尾カンマ

プログラムの自動生成時に有用な末尾カンマ（trailing comma）構文をサポートします。

type e_t: (e0, e1,); end_type
:
var a: array[0..3] of int := [1, 2, 3, 4,]; end_var

終端のセミコロン省略

いくつかのブロックの終端においてセミコロンを省略できます。

program Main
	var v: int; end_var
	var w: int  end_var
end_program

ST言語のプログラムコード内のセミコロン省略

ST言語のプログラムコード内にていくつかの文の終端においてセミコロンを省略できます。

program Main
	var a, b: bool; end_var
//{st}
if a then
	a := b 
	if a then a := b  end_if 
	if a then a := b  end_if 
end_if 
a := b; // 式と式の間には、セミコロンが必要です。
a := b 
//{end}
end_program

基底型なしの名前付き値型

基底型なしで列挙子に値を設定するとき、基底型がdint型の名前付き値型として扱います。

type
	// e_tをdint (e0 := 2, e1 := 3)と解釈します。
	e_t: (e0 := 2, e1 := 3);
end_type

識別子の制約が少ない

変数名等に使用できる識別子の制約が、IEC 61131-3規格の識別子よりも少ないです。キーワードについては、endキーワードが追加されていることを除き、IEC 61131-3規格のキーワードと同等です。

var __a__: int; end_var

オムロン社製Sysmac Studioの名前空間記法をサポート

5.12~オムロン社製Sysmac Studioのバックスラッシュを使用するの名前空間記法をサポートします。例えば、 \\a, a\b\c などをソースコード内で使用できます。

エラーコード

jieccコマンドは、変換時に異常や"異常相当"を検出した場合、標準エラー出力にエラー情報を出力します。

例えば、以下のコマンドの実行結果は、illegal_syntax.txt の2行目のtypeキーワードの位置で構文エラー0x44000003（INVALID_SYNTAX）が発生したことを意味します。

$ jiecc.exe illegal_syntax.txt
illegal_syntax.txt:2.0: error: 0x44000003: TYPE_BLOCK; INVALID_SYNTAX
$

複数のエラー情報が出力されることもあります。個々のエラーは、エラーコード一覧にて確認できる下表に示すエラーレベルと特性を持ちます。

jieccコマンドの戻り値については、SEVERE又はERRORレベルのエラー情報が含まれるときに限り、1以上となります。以降では、エラーコードとその意味について示します。

※1 Jieccは、不正を検出すると変換処理を中止します。一方、既に生成した、変換結果となり得るファイルについては、削除等しません。ファイル書き込み中にメモリ不足になったりするケースがこれに該当します。jieccコマンドの戻り値が1以上であるか、SEVERE、又はERRORのエラーメッセージが表示されている場合、変換結果は不正です。

エラーコード一覧

Jiecc 5.8.4 のエラーコードの一覧を下表に示します。

エラーコード詳細

工事中🙏; コマンド実行時に表示される0x~のエラーコードをエラーコード一覧から検索してヒントを得てください。

ソフトウェア更新履歴

Jieccの既知の不具合や改善項目一覧

Jieccには次に示す既知の不具合や改善項目があります。随時、対応していきます。

Jieccの著作権と利用制限

Jieccは、The 2-Clause BSD Licenseに従うフリーソフトウェアです。詳しくは、ダウンロードしたファイルに同梱されているLICENSE.txtを参照ください。

Jieccに関する問い合わせ

Jieccに関する問い合わせ・改善要望等については、Blogのコメントにて記載するか、管理者メールアドレスに連絡ください。